/* REXX    SKINNY     Prepare a REXXSKEL-based routine for upgrading
                      to a new version of REXXSKEL.
*/
address ISREDIT
"MACRO (opts)"
upper opts
parse var opts "TRACE" tv .
parse value tv "N" with tv .
rc = Trace(tv)

"UP MAX"
"X ALL"                                /* hide everything            */
"F '*/' 1  FIRST "                     /* end of primary comment     */
if rc > 0 then do
   zedsmsg = ""
   zedlmsg = "Couldn't find the end of the opening comment. ",
             "Is this code formatted correctly?"
   address ISPEXEC "SETMSG MSG( ISRZ000 )"
   return
   end

mhtag  = "Modification History"
lmhtag = Length(mhtag)
do forever                             /* find last modification note*/
   "F ' ' 1 PREV "
   if rc > 0 then exit
   "(text)  = LINE .zcsr"
   if Datatype(Substr(text,6,6),"W") then leave
   if Substr(text,6,lmhtag) = mhtag then leave
end
"F 'REXXSKEL'"
"F word 'info' 1"

"F '/*@ HELP'"                         /* end of Help pgf            */
"F '/*@ TOOLKIT_I'"                    /* end of TOOLKIT_INIT pgf    */

"F '/*' 1"                             /* start of imbeds, if any    */
"F '*/' 1 LAST "                       /* end of imbeds, if any      */
"F 'DEIMBED:' 1 first "
"F '/*@ DEIMBED'"

"F first p'=' nx"                      /* position cursor at top     */

exit                                   /*@ SKINNY                    */