/* REXX     MDEL     Delete a member
                     Syntax:  MDEL  member1 ... membern
                     MDEL  --MUST-- be called from a command table
                     entry with ZCTACT of
          SELECT CMD(MDEL |&zdsn |&zmem |&zmemb |&zparm)

*/ arg argline                         /* pro-forma quick-start      */
if argline = "" then do                /* no command table?          */
   address TSO
   parse source     .    .        exec_nm   .
   "CLEAR"
   say
   say exec_nm "cannot proceed because there is no data to process."
   say
   say "You may not have a command-table entry with the proper"
   say "configuration, or you may not have loaded your command table."
   say
   say exec_nm "can only be exercised via a command-table entry.  If  "
   say "you do not have a command table, you cannot run this routine. "
   "NEWSTACK";pull;"DELSTACK"
   "CLEAR"
   exit
   end
address TSO
arg parms "((" opts
opts = Strip( opts,'T','5d'x )
parse var opts "TRACE"  tv  .
parse value tv "N"  with  tv .
rc = Trace( "O" ); rc = Trace( tv )

dlm = Left( parms,1 )
parse var parms  (dlm) zdsn . (dlm) ma (dlm) mb (dlm) delmem
if delmem = "" then do
   say "Syntax error: Must specify a member to be deleted."
   exit
   end                                 /* newmem blank               */

msgstate = Msg( "OFF" )
do Words( delmem )                     /* each member                */
   parse var delmem mbr delmem
   "PDS  '"zdsn"'  DELETE"  mbr
end                                    /* delmem                     */
zz = Msg( msgstate )

exit                                   /*@ MDEL                      */