/* rexx - list open tables */
/* from wjensen.lib.exec */
 address ispexec
 st1l.1= 'table exists in the table input library chain'
 st1l.2= 'table does not exist in the table input library chain'
 st1l.3= 'table input library is not allocated'
 st2l.1= 'table is not open in this logical screen'
 st2l.2= 'table is open in NOWRITE mode in this logical screen'
 st2l.3= 'table is open in WRITE mode in this logical screen'
 st2l.4= 'table is open in SHARED NOWRITE mode in this logical screen'
 st2l.5= 'table is open in SHARED WRITE mode in this logical screen'
 st3l.1= 'table is available for WRITE mode'
 st3l.2= 'table is not available for WRITE mode'
 "control errors return"
 "qtabopen list(list.)"
 say '-'list.0 'tables found'
 do n=1 to list.0
   say '  'list.n
   if left(list.n,3)='ISP' then iterate
   if left(list.n,3)='ISR' then iterate
   "tbstats" list.n "service(srv) retcode(rtc)",
                    "status1(st1) status2(st2) status3(st3)"
 /*say '    service:' srv 'rc:' rtc    */
   say '    status1:' st1l.st1
   say '    status2:' st2l.st2
   say '    status3:' st3l.st3
 end