/* REXX    BLKCOMM     Changes comments in PL/I and REXX from
                       "each-line-a-comment" mode to
                       "multi-line-comment" mode.  Label the start
                       line as ".A" and the end line as ".B"
*/
address ISREDIT
"MACRO (opts)"
upper opts
parse var opts "TRACE" tv .
parse value tv "N" with tv .
rc = Trace("O"); rc = Trace(tv)
if Pos("?",opts) > 0 then call HELP    /*                           -*/
 
"C     '/*'  '/*'  .A  .B"
do while rc=0
   "C  '/*'   '  ' next .a .b"
end
 
"C     '*/'  '*/'  .A  .B  last "
"F   '*/' prev "
do while rc=0
   "C  '*/'   '  ' prev .a .b"
end
 
exit                                   /*@ BLKCOMM                   */
/*
.  ----------------------------------------------------------------- */
HELP:                                  /*@                           */
parse source . . exec_name .
address TSO;"CLEAR" ; say ""
ex_nam = Left(exec_name,8)             /* predictable size           */
 
say "  "ex_nam"      Opens comments in PL/I and REXX.  Requires that two labels"
say "                (.A and .B) be set; the labels may be in either order.    "
say "                A comment block which has a slash-aster/aster-slash on    "
say "                each line will be converted to have a single slash-aster  "
say "                on or after the first line labelled '.A' or '.B' and a    "
say "                single aster-slash on or before the second line labelled  "
say "                '.B' or '.A'.                                             "
say "                                                                          "
say "  Syntax:   "ex_nam"  <no parms>                                          "
address ISPEXEC "CONTROL DISPLAY REFRESH"
exit                                   /*@ HELP                      */