/* REXX    ADDSW      Add additonal text beyond the comment marker.             
                                                                                
           Written by Chris Lewis 19960529                                      
                                                                                
     Impact Analysis                                                            
.    (alias)   ADDHLP                                                           
.    (alias)   ADDELSE                                                          
.    (alias)   ADDLV                                                            
.    (alias)   ADDSKIP                                                          
                                                                                
     Modification History                                                       
     960722 ctl ADDELSE                                                         
     960730 ctl ADDLV                                                           
     991014 fxc ADDSKIP; rigged to place on new line;                           
                                                                                
*/                                                                              
address ISREDIT                                                                 
"MACRO (opts)"                                                                  
if opts <> "" then call HELP           /*                           -*/         
                                                                                
parse source . . exec_name .                                                    
                                                                                
cd.         = "if sw.0error_found then return"                                  
cd.ADDLV    = "if sw.0error_found then leave"                                   
cd.ADDSKIP  = "if \sw.0error_found then,"                                       
cd.ADDHLP   = "if helpmsg ^=" '7f7f'X "then call HELP"                          
cd.ADDELSE  = "if sw.0error_found then nop ; else ,"                            
                                                                                
chgval      = Copies(" ",36)cd.exec_name                                        
                                                                                
"(lp,cp) = CURSOR"                     /* Line and column position   */         
"LINE_AFTER" lp "= DATALINE (chgval)"                                           
                                                                                
"CURSOR =" lp cp                                                                
                                                                                
exit                                                                            
/*                                                                              
.  ----------------------------------------------------------------- */         
HELP:                                  /*@                           */         
address TSO;"CLEAR"                                                             
parse source  .   .   exec_name  .                                              
ex_nam = Left(exec_name,8)             /* predictable size           */         
say "                                                                          "
say "  "ex_nam"      adds a line of REXX code immediately following the cursor."
say "                The contents of the line is determined by the "exec_name" "
say "                synonym which is used to invoke the function.             "
say "                                                                          "
say "  Syntax:   ADDSW     inserts 'if sw.0error_found then return'            "
say "            ADDLV     inserts 'if sw.0error_found then leave'             "
say "            ADDSKIP   inserts 'if \sw.0error_found then,'                 "
say "            ADDHLP    inserts 'if helpmsg ^= '' then call HELP'           "
say "            ADDELSE   inserts 'if sw.0error_found then nop ; else ,'      "
say "                                                                          "
say "   Key one of these names on the command line and place the cursor where  "
say "   the new line is to be inserted.                                        "
say "                                                                          "
say "                                                                          "
say "   Debugging tools provided: none.                                        "
say "                                                                          "
"NEWSTACK"; pull ; "CLEAR" ; "DELSTACK"                                         
address ISPEXEC "CONTROL DISPLAY REFRESH"                                       
exit                                   /*@ HELP                      */